[Coco] Speech and Sound cart manual

[Kevin Diggs]

Hi,

	Should the lines that set the sound mux also be fixed? Here is
my version of the "tone" sample (see line 60 for what I am talking
about):

10  rem initialize variables
20  x=&hff00:y=&hff7e
30  rem reset s/sc
40  poke y-1,1:poke y-1,0
50  rem turn on s/sc sound
60  poke x+1,peek(x+1)and&h77:poke x+3,peek(x+3)or8:poke
x+&h23,peek(x+&h23)or8
70  rem put s/sc into direct address mode
80  gosub320
90  poke y,&haf
100 rem poke a fine tone on channel a
110 gosub320
120 input"enter tone for channel a";t$
130 if t$="q"then poke y-1,1:poke y-1,0:end
140 t=val(t$):if t<1 or t>4095then120
150 poke y,1:poke y,int(t/256)
160 gosub320
170 poke y,0:poke y,t and &hff
180 rem call mixer register
190 gosub320
200 poke y,7
210 rem set mixer to channel a tones only
220 gosub320
230 poke y,62
240 rem call amplitude register for channel a
250 gosub320
260 poke y,8
270 rem set amplitude at maximum -- 15
280 gosub320
290 poke y,15
300 rem go back to change tone on channel a
310 goto120
320 rem check for busy*
330 if (peek(y) and 128)=0then330
340 return

					kevin
tim lindner wrote:
> 
> <secure at ytunnelpro.com> wrote:
> 
> > Thanks people! I snagged it and dropped it into my pending folder. I'm
> > going to run it through some OCR and see if I can't get it reduced in
> > sized a little bit. Thankfully it was saved in lossless format so it'll
> > be tons easier.
> 
> I have taken the liberty to OCR the manual and clean it up. My intent
> will be to re-typeset the manual and to redraw the few illustrations.
> 
> But I would like to ask for help proof reading the text from the OCR
> program.
> 
> Here is the current text file:
> 
> http://home.netcom.com/~tlindner/Download/SSCManual.txt
> 
> The file uses MS-DOS paragraph ending. I chose that since most people
> use Windows computers.
> 
> Please note, there are no line breaks is this text file, just paragraph
> breaks. You need to use a text editor that can wrap paragraphs
> automatically. Please don't insert line breaks.
> 
> If you want to help, just reply to this message and tell me which pages
> you'll check.
> 
> Use the pages numbers from the orginal scans. (But note, the pages
> numbers have been removed from the text file.)
> 
> One last thing:
> 
> The text file reflects some corrections I made to the program listings.
> On all of the 'PEEK(X) AND Y = Z' type lines I changed them to '(PEEK(X)
> AND Y) = Z'. The corrects an order of operations bug throughout the
> program listings.
> 
> And the last correction was made to the Demo program in appendix E. In
> line 3560 I changed the 'K=13' to 'K=17'. This error was found by Robert
> Gault.
> 
> --
> tim lindner
> tlindner at ix.netcom.com                                            Bright
> 
> --
> Coco mailing list
> Coco at maltedmedia.com
> http://five.pairlist.net/mailman/listinfo/coco