[Coco] unfinished would-be CoCo stuff
Steve Bjork
6809er at srbsoftware.com
Tue May 17 00:13:28 EDT 2011
Roger,
I think you win the record for the longest message posted to this group!
Do you know how times I had to swap my iPad 2 to get all the way to the bottom? I don't know because I gave up counting after 50.
Steve
Sent from my iPad
On May 16, 2011, at 8:22 PM, Roger Taylor <operator at coco3.com> wrote:
> For those dabbling in assembly language, here's something I was working on back in 1998 that had about 5 working titles, so I guess it can be called the Studio-3 audio sampler.
>
> I'm just digging through old projects looking for some good ones to include in the Phoenix IDE so people can build and run them in one click. I've got So Many old projects that it makes my head spin. It's funny how authors can sometimes have more unreleased cool stuff than stuff people have actually seen.
>
> Anyway, this is a HQ audio sampler with mouse/joystick hand cursor, waveform monitor, sample window, and some function buttons forrecord, mix-record, reverse, echo, playback, etc.
>
> I noticed some 6309 opcodes in the source, so I'll leave it up to you to make it 6809 compatible again. Anyone is free to expand on this and make something more useful out of it.
>
>
> BUFF EQU 512
> HX EQU 98
> HY EQU 99
> Y1 EQU 100
> X1 EQU 101
> X2 EQU 102
> Y2 EQU 103
> YY EQU 104
> XX EQU 105
> MD EQU 106
> ND EQU 108
> MASK EQU 110
> FCOL EQU 111
> BCOL EQU 112
> CURX EQU 116
> CURY EQU 117
> VAL EQU 118
> COUNT EQU 119
> START EQU 120
> STOP EQU 122
> BFLAG EQU 124
> PAGE EQU 3584
> PBOT EQU 9728
> INDEX EQU 125
> BUTT EQU 126
> REP EQU 127
> ACUM EQU 128
> ACUM1 EQU 130
> PRATE EQU 133
> VOL EQU 134
> ECHO EQU 135
> ECHOBY EQU 136
> ORG 15872
> DIGIT NOP
> ORCC #80
> LDS #1023
> CLR 65344
> CLR 65497
> LDX #DIGIT
> STX <114
> LDA #85
> CLR <113
> LDA #126
> STA 65265 SWI2 VBYTE1
> LDX #PRINT
> STX 65266 SWI2 VBYTE2-3
> LDX #32768
> STX <START
> LDX #32768+8192
> STX <STOP
> LDB #5
> STB <PRATE
> LDB #255
> STB <VOL
> LDB #8
> STB <ECHO
> LDD #$FF00 white on black font
> STD <FCOL
> JSR CLS
> SWI2
> FCB 1
> FDB $0000
> FCB $83 color=white
> FCC /STUDIO-3/
> FCB 13
> FCC /(C) 1998 BY ROGER TAYLOR/
> FCB 13
> FCC /ALL RIGHTS RESERVED/
> FCB 13
> FCC /REQUIRES 6309 CPU, 512K,/
> FCB 13
> FCC /ORCHESTRA-90CC, RIGHT MOUSE,/
> FCB 13
> FCC /LEFT AUDIO SAMPLING CABLE/
> FCB 0
> JSR SHOW
> JSR GMODE
> LDD #$100A
> STD <HX
> JSR BUTDN
> MENU LDD #$FF00
> STD <FCOL
> JSR CLS
> JSR SCOPE
> LDU #BTAB1
> BSR BSEL
> BEQ MENU
> JSR BTPRS
> LDU #BTAB10
> DECA
> LSLA
> JSR [A,U]
> BRA MENU
> BSEL PSHS U
> JSR BTPUT
> BSEL1 JSR HAND allow hand movement until click
> LDB 65280
> ANDB #1
> BNE BSEL1
> JSR BUTUP now wait until user releases button
> LDU ,S get icon# user has clicked on
> LDB ,U+
> STB ,-S
> LDB #1
> STB <BUTT
> BSEL2 LDB ,U+
> LDD ,U++
> STB <X1
> STA <Y1
> ADDB #3
> STB <X2
> ADDA #12
> STA <Y2
> LDB <HX
> CMPB <X1
> BLO BSEL9
> CMPB <X2
> BHI BSEL9
> LDA <HY
> CMPA <Y1
> BLO BSEL9
> CMPA <Y2
> BHI BSEL9
> BRA BSEL0
> BSEL9 INC <BUTT
> DEC ,S
> BNE BSEL2
> CLR <BUTT
> BSEL0 LEAS 1,S
> LDA <BUTT
> PULS U,PC
> BTPUT PSHS D,X,Y
> LDB ,U+
> STB ,-S
> BTP1 LDB ,U+
> DECB
> LDA #64
> MUL
> ADDD #ICONS
> TFR D,Y
> LDB ,U+
> LDA #32
> MUL
> ADDD #PAGE
> TFR D,X
> LDB ,U+
> ABX
> LDB #16
> BTP3 LDA ,Y+
> EORA #85
> STA ,X+
> LDA ,Y+
> EORA #85
> STA ,X+
> LDA ,Y+
> EORA #85
> STA ,X+
> LDA ,Y+
> EORA #85
> STA ,X+
> LEAX 28,X
> DECB
> BNE BTP3
> LDD #$0000
> STD ,X
> STD 2,X
> COMA
> COMB
> STD -512,X
> STD -510,X
> DEC ,S
> BNE BTP1
> LEAS 1,S
> PULS D,X,Y,PC
> BTPRS PSHS D,X,Y
> LDB <BUTT
> DECB
> LDA #3
> MUL
> LEAU D,U
> LEAU 1,U
> BPR1 LDB ,U+
> DECB
> LDA #64
> MUL
> ADDD #ICONS
> TFR D,Y
> LDB ,U+
> LDA #32
> MUL
> ADDD #PAGE
> TFR D,X
> LDB ,U+
> ABX
> LDB #16
> BPR3 LDA ,Y+
> ORA ,X
> STA ,X+
> LDA ,Y+
> ORA ,X
> STA ,X+
> LDA ,Y+
> ORA ,X
> STA ,X+
> LDA ,Y+
> ORA ,X
> STA ,X+
> LEAX 28,X
> DECB
> BNE BPR3
> JSR HAND
> PULS D,X,Y,PC
> PARAM JSR CLS
> SWI2
> FCB 1
> FDB $0701
> FCC /CONTROLS/
> FCB 0
> LDU #BTAB2
> JSR BSEL
> BEQ PARX
> JSR BTPRS
> LDU #BTAB20
> DECA
> LSLA
> JSR [A,U]
> BRA PARAM
> PARX RTS
> MONIT JSR BUTUP
> MON1 JSR GRAB
> LDX #BUFF
> JSR WINDOW
> JSR GSHOW
> LDA 65280
> ANDA #1
> BNE MON1
> RTS
> SCOPE PSHS X,Y,U
> LDX #PAGE
> LDD #$FFFF
> LDY #4096
> SCP1 STD ,X++
> STD ,X++
> STD ,X++
> STD ,X++
> LEAY -8,Y
> BNE SCP1
> LDX #32768
> LDB #0
> STB 65444
> LDB #255
> STB <VAL
> CLR <X2
> LDB ,X+
> LSRB
> STB <Y2
> SCP2 LDA <Y2
> STA <Y1
> LDA <X2
> STA <X1
> LDA ,X+
> LSRA
> STA <Y2
> INC <X2
> JSR LINE
> DEC <VAL
> BNE SCP2
> PULS X,Y,U,PC
> SCAN LDX <START
> PSHS X
> SCN1 JSR WINDOW
> JSR GSHOW
> LDX ,S
> LEAX 4,X
> STX ,S
> LDB 65280
> ANDB #1
> BNE SCN1
> PULS X,PC
> REVERB LDB <ECHO
> LDA #32
> MUL
> STD <ECHOBY
> LDE #0
> RVB010 STE 65444
> INCE
> STE 65445
> DECE
> LDX #32768
> LDY #8192
> RVB020 LDD <ECHOBY
> LEAU D,X point to sample+reg.D
> LSR ,X
> LDB ,U
> LSRB
> ADCB ,X
> STB ,X+
> LEAY -1,Y
> BNE RVB020
> INCE
> CMPE #56
> BLO RVB010
> RTS
> GRAB JSR LJ1EN
> LDB #255
> TFR B,DP
> TRIG1 JSR REPORT
> CMPB #40
> BLS TRIG1
> LDX #BUFF
> LDY #125
> GRAB20 JSR REPORT
> STB ,X+
> LEAY -1,Y
> BNE GRAB20
> CLRB
> TFR B,DP
> RTS
> RECORD ORCC #80
> JSR LJ1EN
> LDB #255
> TFR B,DP
> LDE #0 starting block
> REC010 STE 65444
> LDX #32768
> LDY #8192
> REC020 JSR REPORT
> STB ,X+
> LDA 65280
> ANDA #1
> BEQ RECEND stop recording on mouse click
> LEAY -1,Y
> BNE REC020
> INCE
> CMPE #56 otherwise record all 56 blocks
> BLO REC010
> RECEND CLRB
> TFR B,DP
> RTS
> MIX ORCC #80 mix recording with memory
> JSR LJ1EN
> LDB #255
> TFR B,DP
> LDE #0
> MIX010 STE 65444
> LDX #32768
> LDY #8192
> MIX020 JSR REPORT
> LSR ,X
> LSRB
> ADCB ,X
> STB ,X+
> LDA 65280
> ANDA #1
> BEQ MIXEND
> LEAY -1,Y
> BNE MIX020
> INCE
> CMPE #56
> BLO MIX010
> MIXEND CLRB
> TFR B,DP
> RTS
> PLAY LDB #95 play memory until mouse click
> STB <REP
> ORCC #80
> JSR SNDEN
> PLA002 LDE #0
> PLA005 STE 65444
> LDB #128
> STB <32
> LDX #32768
> LDY #8192
> PLA010 LDA ,X+
> TFR A,B
> STD 65402 left & right channels
> LDA #9
> DECA
> BNE *-1
> LDB 65280
> ANDB #1
> BEQ PLAEND
> LEAY -1,Y
> BNE PLA010
> INCE
> CMPE #56
> BLO PLA005
> TST >REP
> BNE PLA002
> PLAEND CLRB
> TFR B,DP
> RTS
> ACDC STA <MASK
> BPL AC1
> NEGA
> AC1 STA ,-S
> LDA #128
> SUBA ,S+
> RTS
> DCAC STA ,-S
> LDA #128
> SUBA ,S+
> TST <MASK
> BPL DC1
> NEGA
> DC1 RTS
> CLIP LDE #0 clip around 0 volts and adjust
> CLIP10 STE 65444
> LDX #32768
> LDY #8192
> CLIP20 LDA ,X
> JSR ACDC
> SUBA #3
> BGE CLIP30
> CLRA
> CLIP30 JSR DCAC
> STA ,X+
> LEAY -1,Y
> BNE CLIP20
> INCE
> CMPE #56
> BLO CLIP10
> RTS
> ERASE LDE #0 erase memory
> ERA010 STE 65444
> LDX #32768
> LDY #8192
> LDD #$8080
> ERA020 STD ,X++
> LEAY -2,Y
> BLO ERA020
> INCE
> CMPE #56
> BLO ERA010
> PULS B,PC
> MODULA LDX <START
> MOD1 LDU #WAVE1
> LDY #24
> MOD2 LDA ,X
> JSR ACDC
> LDB ,U
> MUL
> JSR DCAC
> STA ,X+
> CMPX <STOP
> BHS MOD5
> LEAY -1,Y
> BNE MOD2
> BRA MOD1
> MOD5 RTS
> BOOST LDE #0 make louder, amplify, boost
> AMP010 STE 65444
> LDX #32768
> LDY #8192
> AMP020 LDA ,X
> JSR ACDC
> LSLA
> JSR DCAC
> STA ,X+
> LEAY -1,Y
> BNE AMP020
> INCE
> CMPE #56
> BLO AMP010
> RTS
> LPASS LDE #0 low-pass/noise filter
> LPA010 STE 65444
> INCE
> STE 65445
> DECE
> LDX #32768
> LDY #8192
> LPA020 LSR ,X mix sample with next sample (+1)
> LDA 1,X
> LSRA
> ADCA ,X
> STA ,X+
> LEAY -1,Y
> BNE LPA020
> INCE
> CMPE #56
> BLO LPA010
> RTS
> HPASS LDE #0
> HPA010 STE 65444
> INCE
> STE 65445
> DECE
> LDX #32768
> LDY #8192
> HPA020 LDA ,X
> SUBA #128
> STA ,-S
> LSR ,X
> LDA 3,X
> LSRA
> ADCA ,X
> SUBA ,S+
> STA ,X+
> LEAY -1,Y
> BNE HPA020
> INCE
> CMPE #56
> BLO HPA010
> RTS
> REVERS LDX <START
> LDY <STOP
> LEAY 1,Y
> REV1 LDA ,X
> LDB ,-Y
> STB ,X+
> STA ,Y
> STX ,--S
> CMPY ,S++
> BHI REV1
> RTS
> LJ1EN LDB 65281
> ANDB #247
> STB 65281
> LDB 65283
> ORB #8
> STB 65283
> LDB 65315
> ANDB #247
> STB 65315
> RTS
> SNDEN PSHS A
> LDA 65281
> ANDA #247
> STA 65281
> LDA 65283
> ORA #8
> STA 65283
> LDA 65315
> ORA #8
> STA 65315
> PULS A,PC
> SHOW PSHS D,X,Y
> JSR VSYNC
> LDX #PAGE
> LDY #PBOT
> SHO1 LDD ,X++
> STD ,Y++
> LDD ,X++
> STD ,Y++
> LDD ,X++
> STD ,Y++
> LDD ,X++
> STD ,Y++
> LDD ,X++
> STD ,Y++
> LDD ,X++
> STD ,Y++
> LDD ,X++
> STD ,Y++
> LDD ,X++
> STD ,Y++
> CMPX #PBOT
> BLO SHO1
> PULS D,X,Y,PC
> CLS PSHS D,X,Y,U
> LDU #PBOT
> LDB <BCOL
> TFR B,A
> TFR D,X
> TFR D,Y
> CLS010 PSHU D,X,Y
> PSHU D,X,Y
> PSHU D,X,Y
> PSHU D,X,Y
> PSHU D,X,Y
> PSHU D
> CMPU #PAGE
> BHS CLS010
> PULS D,X,Y,U,PC
> VSYNC TST 65282
> VSYNC1 TST 65283
> BPL VSYNC1
> RTS
> GMODE BSR VSYNC
> LDA #76
> STA 65424
> LDA #128
> STA 65432
> LDA #8
> STA 65433
> CLR 65434
> CLR 65435
> CLR 65436
> LDD #$E1C0
> STD 65437
> CLR 65439
> LDD #$0037 black,yellow
> STD 65456
> RTS
> CHROUT PSHS D,X,Y,U
> SUBA #32
> LDU #CSET
> LDB #4
> MUL
> LEAU D,U
> LDA <CURY
> LDB #192
> MUL
> LSLB
> ROLA
> ADDD #PAGE
> TFR D,X
> LDB <CURX
> ABX
> LDB <CURX
> LSLB
> LSLB
> ANDB #3
> LDY #BMAP
> LDB B,Y
> STB <MASK
> LDA #4
> STA <COUNT
> CHR1 LDA ,U+
> PSHS A,X
> LDB #7
> CHR2 LDA <MASK
> COMA
> ANDA ,X
> ASL ,S
> BCC CHR3
> PSHS A
> LDA <MASK
> ANDA <FCOL
> BRA CHR4
> CHR3 PSHS A
> LDA <MASK
> ANDA <BCOL
> CHR4 ORA ,S+
> STA ,X
> LEAX 32,X
> DECB
> BNE CHR2
> PULS A,X
> LSR <MASK
> LSR <MASK
> BNE CHR6
> LEAX 1,X
> LDA BMAP
> STA <MASK
> CHR6 DEC <COUNT
> BNE CHR1
> INC <CURX
> PULS D,X,Y,U,PC
> PRINT LDX 10,S
> PRT0 LDA ,X+
> BEQ PRTX
> BMI PRT3
> CMPA #32
> BHS PRT2
> CMPA #11
> BEQ PRT4
> CMPA #10
> BEQ PRT5
> CMPA #13
> BNE PRT1
> CLR <CURX
> INC <CURY
> BRA PRT0
> PRT1 LDD ,X++
> STD <CURX
> BRA PRT0
> PRT2 JSR CHROUT
> BRA PRT0
> PRT3 LDU #CMAP
> ANDA #3
> LDB A,U
> STB <FCOL
> BRA PRT0
> PRT4 LDA <CURX
> STA INDEX
> BRA PRT0
> PRT5 LDA INDEX
> STA <CURX
> INC <CURY
> BRA PRT0
> PRTX STX 10,S
> RTI
> BPRINT PSHS D,X,Y
> LDA #3
> STA <COUNT
> LDY #NADDR
> LDX #NTAB
> LDB <VAL
> NPR0 LDA #$30
> STA ,Y
> NPR2 CMPB ,X
> BCS NPR3
> SUBB ,X
> INC ,Y
> BRA NPR2
> NPR3 LEAY 1,Y
> LEAX 1,X
> DEC <COUNT
> BNE NPR0
> SWI2
> FCB 32
> NADDR FCC /000/
> FDB $2000
> PULS D,X,Y,PC
> WINDOW PSHS X,Y,U
> LDX #PAGE
> LEAX 161,X
> LDD #$0000
> STD ,X
> STD 2,X
> STD 4,X
> STD 6,X
> STD 8,X
> STD 10,X
> STD 12,X
> STD 14,X
> LDD #0
> LDY #64
> LEAX 32,X
> WIN1 LDD #$7FFF
> STD ,X
> LDD #$FFFF
> STD 2,X
> STD 4,X
> STD 6,X
> STD 8,X
> STD 10,X
> STD 12,X
> LDD #$FFFE
> STD 14,X
> LEAX 32,X
> LEAY -1,Y
> BNE WIN1
> LDD #$0000
> STD ,X
> STD 2,X
> STD 4,X
> STD 6,X
> STD 8,X
> STD 10,X
> STD 12,X
> STD 14,X
> LDB #125
> STB <VAL
> LDB #9
> STB <X2
> LDX ,S START OF SAMPLE DATA
> LDB ,X+
> LSRB
> LSRB
> ADDB #6
> STB <Y2
> WIN2 LDA <Y2
> STA <Y1
> LDA <X2
> STA <X1
> LDA ,X+
> LSRA
> LSRA
> ADDA #6
> STA <Y2
> INC <X2
> JSR LINE
> DEC <VAL
> BNE WIN2
> PULS X,Y,U,PC
> GSHOW PSHS X,Y
> LDX #PAGE
> LEAX 161,X
> LDY #66
> GSH1 LDD ,X
> STD 6144,X
> LDD 2,X
> STD 6146,X
> LDD 4,X
> STD 6148,X
> LDD 6,X
> STD 6150,X
> LDD 8,X
> STD 6152,X
> LDD 10,X
> STD 6154,X
> LDD 12,X
> STD 6156,X
> LDD 14,X
> STD 6158,X
> LEAX 32,X
> LEAY -1,Y
> BNE GSH1
> PULS X,Y,PC
> HAND LDA 65315
> ANDA #247
> STA 65315
> LDA 65281
> ANDA #247
> STA 65281
> LDA 65283
> ANDA #247
> STA 65283
> BSR JOY
> LSRB
> LSRB
> LSRB
> STB <HX
> LDA 65281
> ORA #8
> STA 65281
> BSR JOY
> LSRB
> LSRB
> LDA #3
> MUL
> STB <HY
> HPLOT LDA <HY
> LDB #32
> MUL
> ADDD #PAGE
> TFR D,X
> LDB <HX
> ABX
> TFR X,Y
> LDB #18
> STB <COUNT
> HPL0 LDD ,Y
> PSHS D
> LEAY 32,Y
> DEC <COUNT
> BNE HPL0
> LDU #FING
> LDB #18
> STB ,-S
> HPL1 LDD ,X
> ANDA 36,U
> ANDB 37,U
> ORA ,U
> ORB 1,U
> STD ,X
> LEAX 32,X
> LEAU 2,U
> DEC ,S
> BNE HPL1
> LEAS 1,S
> JSR SHOW
> LDB #18
> STB <COUNT
> HPL2 LEAY -32,Y
> PULS D
> STD ,Y
> DEC <COUNT
> BNE HPL2
> RTS
> JOY LDD #$8080
> STA <MASK
> JOY0 STB 65312
> LSR <MASK
> LDA 65280
> BMI JOY1
> SUBB <MASK
> BRA JOY2
> JOY1 ADDB <MASK
> JOY2 LDA <MASK
> CMPA #1
> BNE JOY0
> RTS
> BPS2 RTS
> BUTUP LDB 65280
> ANDB #1
> BEQ BUTUP
> RTS
> BUTDN LDB 65280
> ANDB #1
> BNE BUTDN
> RTS
> LINE PSHS X
> LDD <Y1
> STD <YY
> LDX #LIN101
> LDA <X2
> SUBA <X1
> BHS LIN010
> NEGA
> LDX #LIN103
> LIN010 STA <MD+1
> CLR <MD
> LDY #LIN102
> LDA <Y2
> SUBA <Y1
> BHS LIN020
> NEGA
> LDY #LIN104
> LIN020 STA <ND+1
> CLR <ND
> LDD <MD
> CMPD <ND
> BHS LIN025
> EXG X,Y
> LDU <ND
> STD <ND
> STU <MD
> LIN025 LDD <MD
> STB <COUNT
> LSRB
> LDA <MD+1
> ANDA #1
> BEQ LIN028
> CMPX #LIN103
> BLO LIN028
> DECB
> LIN028 CLRA
> LIN030 PSHS D,X,Y
> LDX #PAGE
> LDB <YY
> LDA #32
> MUL
> LEAX D,X
> LDB <XX
> TFR B,A
> LSRB
> LSRB
> LSRB
> ABX
> ANDA #7
> LDY #BMAP2
> LDB ,X
> ANDB A,Y
> STB ,X
> PULS D,X,Y
> JSR ,X
> ADDD <ND
> CMPD <MD
> BLO LIN050
> SUBD <MD
> JSR ,Y
> LIN050 DEC <COUNT
> BNE LIN030
> PULS X,PC
> LIN101 INC <XX
> RTS
> LIN102 INC <YY
> RTS
> LIN103 DEC <XX
> RTS
> LIN104 DEC <YY
> RTS
> REPORT LDB #128
> STB <32
> LDA <0
> BMI REPA64
> REPS64 SUBB #64
> STB <32
> LDA <0
> BMI REPA32
> REPS32 SUBB #32
> STB <32
> LDA <0
> BMI REPA16
> REPS16 SUBB #16
> STB <32
> LDA <0
> BMI REPA8
> REPS8 SUBB #8
> STB <32
> LDA <0
> BMI REPA4
> REPS4 SUBB #4
> STB <32
> LDA <0
> BMI REPA2
> REPS2 SUBB #2
> RTS
> REPA64 ADDB #64
> STB <32
> LDA <0
> BPL REPS32
> REPA32 ADDB #32
> STB <32
> LDA <0
> BPL REPS16
> REPA16 ADDB #16
> STB <32
> LDA <0
> BPL REPS8
> REPA8 ADDB #8
> STB <32
> LDA <0
> BPL REPS4
> REPA4 ADDB #4
> STB <32
> LDA <0
> BPL REPS2
> REPA2 ADDB #2
> RTS
> CMAP FDB $0055
> FDB $AAFF
> BMAP FDB $C030
> FDB $0C03
> BMAP2 FDB $7FBF
> FDB $DFEF
> FDB $F7FB
> FDB $FDFE
> NTAB FCB 100
> FCB 10
> FCB 1
> BTAB1 FCB 18
> FCB 1
> FDB $8401
> FCB 2
> FDB $8406
> FCB 3
> FDB $840B
> FCB 4
> FDB $8410
> FCB 5
> FDB $8415
> FCB 6
> FDB $841A
> FCB 7
> FDB $9802
> FCB 8
> FDB $9807
> FCB 9
> FDB $980C
> FCB 10
> FDB $9811
> FCB 11
> FDB $9816
> FCB 12
> FDB $981B
> FCB 13
> FDB $AC01
> FCB 14
> FDB $AC06
> FCB 15
> FDB $AC0B
> FCB 16
> FDB $AC10
> FCB 17
> FDB $AC15
> FCB 6
> FDB $AC1A
> BTAB10 FDB RECORD
> FDB MIX
> FDB PLAY+1
> FDB PLAY
> FDB MONIT
> FDB MONIT
> FDB ERASE
> FDB LPASS
> FDB HPASS
> FDB REVERB
> FDB REVERS
> FDB BOOST
> FDB CLIP
> FDB CLIP
> FDB MODULA
> FDB PARAM
> FDB MONIT
> FDB MONIT
> BTAB2 FCB 2
> FCB 10
> FDB $6002
> FCB 13
> FDB $6008
> BTAB20 FDB MONIT
> FDB MONIT
> FING FDB $0000
> FDB $0700
> FDB $0F00
> FDB $0F00
> FDB $0F00
> FDB $0F00
> FDB $0F00
> FDB $17C0
> FDB $2FF0
> FDB $2FFC
> FDB $3FFC
> FDB $3FFC
> FDB $3FFC
> FDB $3FFC
> FDB $3FFC
> FDB $0FF0
> FDB $0FF0
> FDB $0000
> FMASK FDB $E03F
> FDB $E03F
> FDB $C03F
> FDB $C03F
> FDB $C03F
> FDB $C03F
> FDB $C03F
> FDB $000F
> FDB $0003
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $C003
> FDB $C003
> FDB $C003
> CSET FDB $0000
> FDB $0000
> FDB $00FA
> FDB $0000
> FDB $E000
> FDB $E000
> FDB $28FE
> FDB $2800
> FDB $74D6
> FDB $5C00
> FDB $CE10
> FDB $E600
> FDB $6498
> FDB $6400
> FDB $00E0
> FDB $3000
> FDB $007C
> FDB $8200
> FDB $827C
> FDB $0000
> FDB $5438
> FDB $5400
> FDB $107C
> FDB $1000
> FDB $0002
> FDB $0C00
> FDB $1010
> FDB $1000
> FDB $0002
> FDB $0000
> FDB $0E10
> FDB $E000
> FDB $FE82
> FDB $FE00
> FDB $42FE
> FDB $0200
> FDB $9E92
> FDB $F200
> FDB $9292
> FDB $FE00
> FDB $F010
> FDB $FE00
> FDB $F292
> FDB $9E00
> FDB $FE92
> FDB $9E00
> FDB $8080
> FDB $FE00
> FDB $FE92
> FDB $FE00
> FDB $F292
> FDB $FE00
> FDB $006C
> FDB $0000
> FDB $026C
> FDB $0000
> FDB $3844
> FDB $8200
> FDB $2828
> FDB $2800
> FDB $8244
> FDB $3800
> FDB $C09A
> FDB $F000
> FDB $4C54
> FDB $7C00
> FDB $7E90
> FDB $7E00
> FDB $FE92
> FDB $6C00
> FDB $FE82
> FDB $C600
> FDB $FE82
> FDB $7C00
> FDB $FE92
> FDB $8200
> FDB $FE90
> FDB $8000
> FDB $FE82
> FDB $9E00
> FDB $FE10
> FDB $FE00
> FDB $82FE
> FDB $8200
> FDB $0482
> FDB $FC00
> FDB $FE10
> FDB $EE00
> FDB $FE02
> FDB $0200
> FDB $FE40
> FDB $FE00
> FDB $FE80
> FDB $FE00
> FDB $FE82
> FDB $FE00
> FDB $FE90
> FDB $F000
> FDB $7C8A
> FDB $7E00
> FDB $FE90
> FDB $6E00
> FDB $F292
> FDB $9E00
> FDB $80FE
> FDB $8000
> FDB $FE02
> FDB $FE00
> FDB $FC02
> FDB $FC00
> FDB $FE04
> FDB $FE00
> FDB $EE10
> FDB $EE00
> FDB $F01E
> FDB $F000
> FDB $8E92
> FDB $E200
> FDB $00FE
> FDB $8203
> FDB $FF00
> FDB $FF00
> FDB $82FE
> FDB $0000
> FDB $40FE
> FDB $4000
> FDB $1038
> FDB $6C00
> WAVE1 FDB $FFFF
> FDB $F0E0
> FDB $E00E
> FDB $A080
> FDB $6040
> FDB $2010
> FDB $0440
> FDB $2040
> FDB $6080
> FDB $2030
> FDB $C0F0
> FDB $FFFF
> ICONS FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $C000
> FDB $0000
> FDB $F000
> FDB $00C0
> FDB $FC00
> FDB $00C0
> FDB $FF00
> FDB $03F0
> FDB $FFC0
> FDB $00C0
> FDB $FF00
> FDB $00C0
> FDB $FC00
> FDB $0000
> FDB $F000
> FDB $0000
> FDB $C000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON2 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $C000
> FDB $0000
> FDB $F000
> FDB $00C0
> FDB $FC00
> FDB $00C0
> FDB $FF00
> FDB $03FF
> FDB $FFC0
> FDB $00C0
> FDB $FF00
> FDB $00C0
> FDB $FC00
> FDB $0000
> FDB $F000
> FDB $0000
> FDB $C000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON3 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $000C
> FDB $0000
> FDB $000F
> FDB $0000
> FDB $000F
> FDB $C000
> FDB $000F
> FDB $F000
> FDB $000F
> FDB $FC00
> FDB $000F
> FDB $F000
> FDB $000F
> FDB $C000
> FDB $000F
> FDB $0000
> FDB $000C
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON4 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0030
> FDB $0000
> FDB $003C
> FDB $0000
> FDB $0FFF
> FDB $0FC0
> FDB $0C3C
> FDB $00C0
> FDB $0C30
> FDB $00C0
> FDB $0C00
> FDB $00C0
> FDB $0C00
> FDB $00C0
> FDB $0C00
> FDB $00C0
> FDB $0FFF
> FDB $FFC0
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON5 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $003F
> FDB $C000
> FDB $0030
> FDB $C000
> FDB $0030
> FDB $C300
> FDB $0030
> FDB $C3C0
> FDB $0FF0
> FDB $FFF0
> FDB $0000
> FDB $03C0
> FDB $0000
> FDB $0300
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON6 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0300
> FDB $0003
> FDB $0300
> FDB $0003
> FDB $0300
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0FFF
> FDB $FFFC
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0033
> FDB $3330
> FDB $0003
> FDB $0300
> FDB $0000
> FDB $0300
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON7 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0C00
> FDB $0030
> FDB $0FFF
> FDB $FFF0
> FDB $0C00
> FDB $0030
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON8 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $00FC
> FDB $0000
> FDB $00CC
> FDB $0000
> FDB $03CF
> FDB $0030
> FDB $0303
> FDB $0030
> FDB $0F03
> FDB $C030
> FDB $0C00
> FDB $C030
> FDB $0C00
> FDB $C0F0
> FDB $0C00
> FDB $C0C0
> FDB $0C00
> FDB $F3C0
> FDB $0000
> FDB $3300
> FDB $0000
> FDB $3F00
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON9 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $03F3
> FDB $F3F0
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $0333
> FDB $3330
> FDB $033F
> FDB $3F30
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON10 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $000C
> FDB $0030
> FDB $000C
> FDB $0030
> FDB $00CC
> FDB $0330
> FDB $0CCC
> FDB $3330
> FDB $0CCC
> FDB $3330
> FDB $0CCC
> FDB $3330
> FDB $00CC
> FDB $0330
> FDB $000C
> FDB $0030
> FDB $000C
> FDB $0030
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON11 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0030
> FDB $0000
> FDB $00F0
> FDB $0000
> FDB $03FF
> FDB $FFC0
> FDB $00F0
> FDB $00C0
> FDB $0030
> FDB $00C0
> FDB $0000
> FDB $00C0
> FDB $0000
> FDB $00C0
> FDB $000F
> FDB $FFC0
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON12 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0300
> FDB $0000
> FDB $0300
> FDB $0030
> FDB $0300
> FDB $003C
> FDB $0300
> FDB $0FFF
> FDB $3FF0
> FDB $003C
> FDB $0300
> FDB $0030
> FDB $0300
> FDB $0000
> FDB $0300
> FDB $0000
> FDB $0300
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON13 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0003
> FDB $0000
> FDB $0003
> FDB $0000
> FDB $0C00
> FDB $0030
> FDB $0FFF
> FDB $FFF0
> FDB $0C00
> FDB $0030
> FDB $0003
> FDB $0000
> FDB $0003
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON14 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $C000
> FDB $000F
> FDB $FC00
> FDB $00FF
> FDB $FFC0
> FDB $00FF
> FDB $FFC0
> FDB $03FF
> FDB $FFF0
> FDB $03FF
> FDB $FFF0
> FDB $0FFF
> FDB $3FFC
> FDB $03FF
> FDB $FFF0
> FDB $03FF
> FDB $FFF0
> FDB $00FF
> FDB $FFC0
> FDB $00FF
> FDB $FFC0
> FDB $000F
> FDB $FC00
> FDB $0000
> FDB $C000
> FDB $0000
> FDB $0000
> ICON15 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0FFF
> FDB $FFF0
> FDB $0F00
> FDB $00F0
> FDB $0F00
> FDB $00F0
> FDB $0CC0
> FDB $0330
> FDB $0C30
> FDB $0C30
> FDB $0C30
> FDB $0C30
> FDB $0C0C
> FDB $3030
> FDB $0C0C
> FDB $3030
> FDB $0C03
> FDB $C030
> FDB $0C00
> FDB $0030
> FDB $0FFF
> FDB $FFF0
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON16 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0030
> FDB $3000
> FDB $000C
> FDB $C000
> FDB $000C
> FDB $C000
> FDB $0003
> FDB $0000
> FDB $00FF
> FDB $FC00
> FDB $000C
> FDB $C000
> FDB $000C
> FDB $C000
> FDB $0030
> FDB $3000
> FDB $0030
> FDB $3000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> ICON17 FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0FFF
> FDB $FFF0
> FDB $0EAA
> FDB $BFF0
> FDB $0FFF
> FDB $FF00
> FDB $0EAA
> FDB $BF00
> FDB $0FFF
> FDB $FFF0
> FDB $0FFF
> FDB $FFF0
> FDB $0FFF
> FDB $FFF0
> FDB $0FFF
> FDB $FFF0
> FDB $0FFF
> FDB $FFF0
> FDB $0FFF
> FDB $BFF0
> FDB $0FFF
> FDB $BFF0
> FDB $0FFF
> FDB $FFF0
> FDB $0000
> FDB $0000
> FDB $0000
> FDB $0000
> END DIGIT
> --
> ~ Roger Taylor
>
>
> --
> Coco mailing list
> Coco at maltedmedia.com
> http://five.pairlist.net/mailman/listinfo/coco
More information about the Coco
mailing list