[Coco] Easy way to copy 40 track disks to the CoCoSDC?

[tim lindner]

Daniel Campos <daniel.campus at gmail.com> wrote:

> I'm assuming that my disk have 40 tracks, but how can I be certain of
> that ? How to identify if a disk has 40 tracks ? There is a utility to
> identify that ?

I won't really be able to test the hack for a few weeks.

I think a quick internet search with the drives model number will return
the number of tracks it supports.

On the drives I have I can count the audible track steping. When it goes
from 35 to 36 it will sound different if the drive is a 35 track drive.

Here is a program I use on the CoCo 3, with my 40 track disk drive to
backup 40 track disks. It probes the disk to look for the last track:

5 REM READ REAL DISK IN DRIVE 0 COPY TO DISK IMAGE IN DRIVE 1
6 REM FOR COCO 3 AND SDC
10 DRIVE 0,OFF
20 CLEAR 2000
30 ON ERR GOTO 100
40 POKE &HD534,127 : REM SET TRACK LIMIT TO 127
50 T=34
60 PRINT "TESTING T:";T
70 DSKI$0,T,1,A$,B$
80 T=T+1
90 GOTO 60
100 REM FOUND MAX TRACK
110 M=T-1
120 ON ERR GOTO 280
130 T=0
140 S=1
150 INPUT "DISK NAME:";C$
160 IF RIGHT$(C$,4)=".DSK" THEN 180
170 C$=C$+".DSK"
180 DRIVE 1,C$,NEW
190 REM
200 DSKI$ 0,T,S,A$,B$
210 REM
220 DSKO$ 1,T,S,A$,B$
230 S=S+1
240 IF S=19 THEN S=1:T=T+1
250 IF T=M+1 THEN END
260 PRINT ".";
270 GOTO 190
280 PRINT:PRINT "ERROR T:";T;" S:";S
290 IF ERLIN<>200 THEN STOP
300 A$=STRING$(128,CHR$(255))
310 B$=A$
320 GOTO 220



-- 
tim lindner
tlindner at macmess.org                                              Bright