[Coco] Attn Darren: CoCoSDC standalone commands?

[Darren A]

On Sat, Dec 27, 2014 at 8:16 PM, Allen Huffman <alsplace at pobox.com> wrote:

>
> But for my RGB-DOS SCSI disks (EZ125) and my CompactFlash HDB-DOS, I need
> a way to move from RGB-DOS to the CoCoSDC....
>


Below is a BASIC program I sometimes use when SDC-DOS is not present. It's
a little slow and definitely more cumbersome than entering commands in
SDC-DOS, but it gets the job done.  Save this program somewhere on your CF
card or SCSI disk so you can run it when using RGB/HDB DOS.

It is also available as a DSK file:
<
https://drive.google.com/file/d/0B_o8KocZC3DSekxUdlhhUU1hNXM/view?usp=sharing
>


10 OS=PEEK(&HFF7F):INPUT "MPI SLOT#";SL
20 IF SL<1 OR SL>4 THEN 10
30 INPUT "SDC DRIVE#";DR
40 IF DR<>0 AND DR<>1 THEN 30
50 LINE INPUT "COMMAND? ";C$
60 IF LEN(C$)<2 OR MID$(C$,2,1)<>":" THEN 50
70 C$=C$+CHR$(0):P=VARPTR(C$)
80 P=PEEK(P+2)*256+PEEK(P+3)
90 POKE &HFF7F,OS AND 240 OR SL
100 POKE &HFF40,67:POKE &HFF49,0
110 POKE &HFF4A,0:POKE &HFF48,DR+224
120 A=&HFF4A:B=&HFF4B
130 FOR I=P TO P+254 STEP2:POKE A,PEEK(I):POKE B,PEEK(I+1):NEXT
140 ST=PEEK(&HFF48):IF ST AND 1 THEN 140
150 POKE &HFF40,0:POKE &HFF7F,OS
160 IF ST AND 128 THEN PRINT "ERROR";ST


When you run the program you will be asked for the MPI slot number
containing the CoCo SDC (1-4).  You could edit line 10 to remove the INPUT
statement and just set variable SL equal to the slot number.

Next you will be asked for the SDC Drive Number (0 or 1) to which the
command will be applied. Enter 0 for commands that don't apply to a
specific drive number, or just press ENTER.

Finally you will be asked to enter a command string. Command strings begin
with a letter and a colon (:). Immediately following the colon is a path
name to a file or directory on the SD card.

Commands Available:

D:  set current directory on SD card
K:  create new directory
M:  mount or eject a disk image
N:  create (if necessary) and mount a DSK file
X:  delete a file or an empty directory

Examples:

--------------------------------------------
Set current directory to /GAMES/ARCADE

SDC DRIVE#? 0
COMMAND? D:/GAMES/ARCADE

--------------------------------------------
Mount Donkey Kong image in drive 0

SDC DRIVE#? 0
COMMAND? M:DONKEY.DSK

--------------------------------------------
Eject the disk image in drive 1

SDC DRIVE#? 1
COMMAND? M: